戰士巨集整理

整合技能

---

命令之吼、戰鬥怒吼
#showtooltip
/cast [btn:2] [mod] 命令之吼; 戰鬥怒吼

如果以右鍵點擊、或是按著控制鍵（ctrl、alt、shift）時，使用命令之吼；否則使用戰鬥怒吼。

---

挫志怒吼、雷霆一擊
#showtooltip
/cast [btn:2] [mod] 挫志怒吼; 雷霆一擊

如果以右鍵點擊、或是按著控制鍵（ctrl、alt、shift）時，使用挫志怒吼；否則使用雷霆一擊。

---

反擊風暴、盾牆＆魯莽
#showtooltip [stance:1] 反擊風暴;[stance:2] 盾牆; 魯莽
/cast [stance:1] 反擊風暴;[stance:2,equipped:盾牌] 盾牆;[stance:3] 魯莽

依照姿態的不同使用不同的技能。

#showtooltip [stance:1] 反擊風暴;[stance:2] 盾牆; 魯莽
/cast [stance:1] 反擊風暴;[stance:2,equipped:盾牌] 盾牆;[stance:3] 魯莽
/script s={"看我的反擊風暴！","盾牆！硬梆梆的12秒！","來人呀！發～飆啦～"};SendChatMessage(s[GetShapeshiftForm(true)], "YELL");

除了依照姿態的不同使用不同的技能之外，同時喊出不一樣的台詞。紅字部份分別為三個技能所對應台詞，修改時應注意不要動到紅字以外的內容。

---

嘲諷
#showtooltip 嘲諷
/cast [stance:2] 嘲諷; 防禦姿態

如果是在防禦姿態下則使用嘲諷；否則切換為防禦姿態。

#showtooltip 嘲諷
/cast [stance:2] 嘲諷; 防禦姿態
/equipslot [btn:2] [mod] 16 主手裝備
/equipslot [btn:2] [mod] 17 附手裝備

如果是在防禦姿態下則使用嘲諷；否則切換為防禦姿態。以右鍵點擊、或是按著控制鍵（ctrl、alt、shift）時，同時進行切換裝備的動作。

#showtooltip 嘲諷
/cast [stance:2] 嘲諷; 防禦姿態
/equipset [btn:2] [mod] 套裝名稱

功能與上一個巨集相同，但切換裝備的動作不是直接指定名稱，而是選擇設定於裝備管理員中的套裝。

---

法術反射
#showtooltip 法術反射
/cast [stance:2,equipped:盾牌] 法術反射; [nostance:2] 防禦姿態
/equipslot [noequipped:盾牌] 16 主手裝備
/equipslot [noequipped:盾牌] 17 附手裝備

如果是在防禦姿態下，而且裝備了盾牌時，使用嘲諷。如果不是防禦姿態則切換為防禦姿態；如果沒有裝備盾牌則切換裝備。

#showtooltip 法術反射
/cast [stance:2,equipped:盾牌] 法術反射; [nostance:2] 防禦姿態
/equipset [btn:2] [mod] 套裝名稱

功能與上一個巨集相同，但切換裝備的動作不是直接指定名稱，而是選擇設定於裝備管理員中的套裝。

---

盾擊、拳擊
#showtooltip [equipped:盾牌] 盾擊; 拳擊
/cast [stance:1/2,equipped:盾牌] 盾擊;[stance:1/2,noequipped:盾牌] 狂暴姿態; 拳擊

如果是在戰鬥、防禦姿態下，有裝備盾牌時使用盾擊；沒有裝備盾牌時切換成狂暴姿態。如果在狂暴姿態下，使用拳擊。

---

衝鋒、壓制
#showtooltip [combat] 壓制; 衝鋒
/cast [nostance:1] 戰鬥姿態;[combat] 壓制; 衝鋒

在戰鬥中使用壓制；不在戰鬥中使用衝鋒。

---

衝鋒、攔截
#showtooltip [combat] 攔截; 衝鋒
/cast [stance:1,nocombat] 衝鋒;[nocombat] 戰鬥姿態; [stance:1/2] 狂暴姿態; 攔截

在戰鬥中使用攔截；不在戰鬥中使用衝鋒。

---

盾牌格擋、盾牌猛擊
#showtooltip
/cast [btn:2] [mod] 盾牌格擋
/cast 盾牌猛擊

使用盾牌猛擊。如果以右鍵點擊、或是按著控制鍵（ctrl、alt、shift）時，則在使用盾牌猛擊之前先使用盾牌格擋。

智慧技能

---

阻擾
#showtooltip [help] [@targettarget,help] [] 阻擾
/cast [stance:1/3] 防禦姿態;[@focus,btn:2,help] [help] [@targettarget,help] 阻擾

對友善目標、或目標的友善目標使用；以右鍵點擊，則改為對focus對象使用。如果不在防禦姿態，則切換為防禦姿態。

---

嘲諷
#showtooltip [@mouseover,exists,nodead,nohelp] [] 嘲諷
/cast [nostance:2] 防禦姿態;[@mouseover,exists,nodead,nohelp] [] 嘲諷

對滑鼠所指定的對象或對目標使用嘲諷；若不在防禦姿態下則改為切換防禦姿態。

---

震盪猛擊
#showtooltip
/cast [@mouseover,exists,nodead,nohelp] [] 震盪猛擊

對滑鼠所指定的對象或對目標使用震盪猛擊。

---

破甲攻擊
#showtooltip
/cast [@mouseover,exists,nodead,nohelp] [] 破甲攻擊

對滑鼠所指的對象或對目標使用破甲攻擊。由於破甲攻擊不會造成傷害，所以亦可用於被控場的目標上。

---

破甲攻擊、挫敗
#showtooltip
/cast [@mouseover,exists,nodead,nohelp] 破甲攻擊; 挫敗

對滑鼠所指的敵對對象使用破甲攻擊，或對目標使用挫敗。

---

熱血猛擊
#showtooltip
/cast 猛擊
/stopcasting

此巨集僅供具有熱血沸騰天賦之戰士使用。
當熱血沸騰被觸發時，才允許使用猛擊。

技能連鎖

---

攔截、英勇烈怒
#showtooltip
/castsequence reset=30 攔截, 英勇烈怒

使用攔截，如果還在CD中則改用英勇烈怒。如果攔截的CD時間有受到天賦或裝備的影響而縮短，須更改reset的時間。

---

衝鋒、攔截
#showtooltip
/castsequence reset=15 衝鋒, 攔截

此巨集僅供具有征戰者天賦之戰士使用。使用衝鋒，如果還在CD中則改用攔截。

---

盾擊、拳擊＆英勇投擲
#showtooltip
/castsequence [stance:1/2,equipped:盾牌] reset=12 盾擊, 英勇投擲;[stance:3] reset=10 拳擊, 英勇投擲
/cast [stance:1/2,noequipped:盾牌] 狂暴姿態

使用盾擊或拳擊，如果還在CD中則改用英勇投擲。

---

雷霆一擊、挫志怒吼
#showtooltip
/castsequence [nobtn:2,nomod] reset=6 雷霆一擊, 挫志怒吼
/cast [btn:2] [mod] 挫志怒吼

使用雷霆一擊，如果雷霆一擊還在CD中，或以右鍵點擊、亦或是按著控制鍵（ctrl、alt、shift）時，使用挫志怒吼。

---

雷霆一擊、震攝波
#showtooltip
/castsequence reset=6 雷霆一擊, 震攝波

使用雷霆一擊，如果還在CD中則改用震攝波。雷霆一擊放在前面的原因是因為雷霆一擊的CD比較短。若將CD時間比較長的技能放在前面，容易造成排在後面技能CD過了，但卻因為前面的技能還在CD而卡住無法使用。

---

嘲諷、懲戒痛擊
#showtooltip
/castsequence reset=8 嘲諷, 懲戒痛擊

使用嘲諷，如果還在CD中則改用懲戒痛擊。

#showtooltip
/castsequence [@mouseover,exists,nodead,nohelp] [] reset=8 嘲諷, 懲戒痛擊

對滑鼠所指定的對象、或對目標使用嘲諷，如果還在CD中則改用懲戒痛擊。

---

破釜沉舟、狂怒恢復
#showtooltip
/castsequence reset=300 破釜沉舟, 狂怒恢復

先使用破釜沉舟之後再使用狂怒恢復，以加強恢復效果。